pragma ComponentBehavior: Bound
import QtQuick
import QtCore
import QtQuick.Controls as QQC2
import QtQuick.Layouts

import org.kde.kirigami as Kirigami
import org.kde.kirigamiaddons.formcard as FormCard

import org.deprecated.kodereviewer 1.0

Kirigami.ScrollablePage {
    id: root

    property var pullRequest
    property NetworkManager connection

    Kirigami.Theme.colorSet: Kirigami.Theme.View
    Kirigami.Theme.inherit: false

    property string currentView: "info"

    actions: [
        Kirigami.Action {
            id: reviewChangesAction
            text: "Review changes"
            icon.name: "preview-symbolic"
            enabled: !!root.pullRequest
            onTriggered: reviewChangesDialog.open()
        },
        Kirigami.Action {
            id: openFiles
            text: "Files"
            icon.name: "file-catalog-symbolic"
            enabled: !!root.pullRequest
            onTriggered: {
                contextDrawer.open()
            }
        }
    ]

    ReviewDialog {
        id: reviewChangesDialog
        onAccepted: {
            root.connection.createReview(
                root.pullRequest.number, root.pullRequest.last_commit,
                reviewBodyText, event
            )
            clearForm()
        }
    }

    Loader {
        id: commentModelLoader
        active: !!root.pullRequest
        sourceComponent: CommentModel {
            id: commentModel
            pullRequest: root.pullRequest

            onPullRequestChanged: root.connection.getPullRequestComments(root.pullRequest.number)
        }
    }

    Loader {
        id: fileModelLoader
        active: !!root.pullRequest
        sourceComponent: FileModel {
            id: fileModel
            pullRequest: root.pullRequest

            onPullRequestChanged: root.connection.getFiles(root.pullRequest.number)
        }
    }

    Loader {
        id: treeFileModelLoader
        active: !!root.pullRequest
        sourceComponent: TreeFileModel {
            pullRequest: root.pullRequest
        }
    }

    KRContextDrawer {
        id: contextDrawer
        enabled: !!root.pullRequest
        modal: true
        model: treeFileModelLoader.item
    }

    Kirigami.PlaceholderMessage {
        visible: !root.pullRequest
        anchors.centerIn: parent
        icon.name: "org.deprecated.kodereviewer"
        text: "Select a pull request"
    }

    PullRequestDescription {
        visible: !!root.pullRequest && root.currentView == "info"
        pullRequest: root.pullRequest
        anchors.fill: parent
    }

    Kirigami.CardsListView {
        visible: !!root.pullRequest && root.currentView == "comments"
        anchors.fill: parent
        // Layout.fillWidth: true
        // Layout.fillHeight: true
        model: commentModelLoader.item
        delegate: CommentDelegate {}
        footerPositioning: ListView.OverlayFooter
    }

    FilesView {
        visible: !!root.pullRequest && root.currentView == "files"
        fileModel: fileModelLoader.item
    }

    footer: Kirigami.NavigationTabBar {
        actions: [
            Kirigami.Action {
                icon.name: "info"
                text: i18n("Info")
                onTriggered: root.currentView = "info"
            },
            Kirigami.Action {
                icon.name: "comment-symbolic"
                text: i18n("Comments")
                onTriggered: root.currentView = "comments"

            },
            Kirigami.Action {
                icon.name: "file-catalog-symbolic"
                text: i18n("Files")
                onTriggered: root.currentView = "files"
            }
        ]
    }
}