pragma ComponentBehavior: Bound
import QtQuick
import QtCore
import QtQuick.Controls as QQC2
import QtQuick.Layouts

import org.kde.kirigami as Kirigami
import org.kde.kirigamiaddons.formcard as FormCard

import org.deprecated.kodereviewer 1.0

Kirigami.ScrollablePage {
    id: root

    property var pullRequest
    property NetworkManager connection

    Kirigami.Theme.colorSet: Kirigami.Theme.View
    Kirigami.Theme.inherit: false

    property string currentView: "info"


    CommentModel {
        id: commentModel
        pullRequest: root.pullRequest

        onPullRequestChanged: root.connection.getPullRequestComments(root.pullRequest.number)
    }


    Kirigami.PlaceholderMessage {
        visible: !root.pullRequest
        anchors.centerIn: parent
        icon.name: "org.deprecated.kodereviewer"
        text: "Select a pull request"
    }

    ColumnLayout {
        id: mainLayout
        visible: !!root.pullRequest && root.currentView == "info"

        spacing: Kirigami.Units.largeSpacing * 2

        Kirigami.Heading {
            Layout.fillWidth: true
            Layout.alignment: Qt.AlignHCenter
            leftPadding: Kirigami.Units.largeSpacing
            rightPadding: Kirigami.Units.largeSpacing
            level: 1
            text: root.pullRequest ? root.pullRequest.title : ""
            wrapMode: Text.WordWrap
        }

        Kirigami.ListSectionHeader {
            Layout.fillWidth: true
            text: "description"
        }

        MarkdownLabel {
            Layout.fillWidth: true
            Layout.fillHeight: false
            leftPadding: Kirigami.Units.largeSpacing
            rightPadding: Kirigami.Units.largeSpacing
            text: root.pullRequest ? root.pullRequest.body : ""
        }
    }
    ColumnLayout {
        visible: !!root.pullRequest && root.currentView == "comments"
        Repeater {
            model: commentModel
            delegate: CommentDelegate {}
        }
    }

    footer: Kirigami.NavigationTabBar {
        actions: [
            Kirigami.Action {
                icon.name: "info"
                text: i18n("Info")
                onTriggered: root.currentView = "info"
            },
            Kirigami.Action {
                icon.name: "comment-symbolic"
                text: i18n("Comments")
                onTriggered: root.currentView = "comments"

            },
            Kirigami.Action {
                icon.name: "file-catalog-symbolic"
                text: i18n("Files")
                onTriggered: root.currentView = "files"
            }
        ]
    }
}