1 files changed, 75 insertions, 0 deletions
diff --git a/kodereviewer/qml/FilesChangedPage.qml b/kodereviewer/qml/FilesChangedPage.qml
new file mode 100644
index 0000000..e74b59c
--- /dev/null
+++ b/kodereviewer/qml/FilesChangedPage.qml
@@ -0,0 +1,75 @@
+pragma ComponentBehavior: Bound
+import QtQuick
+import QtCore
+import QtQuick.Controls as QQC2
+import QtQuick.Layouts
+
+import org.kde.kirigami as Kirigami
+import org.kde.kirigamiaddons.formcard as FormCard
+import org.kde.kirigamiaddons.components as KirigamiComponents
+
+import org.deprecated.kodereviewer 1.0
+
+Kirigami.ScrollablePage {
+    id: root
+
+    property var pullRequest
+    property NetworkManager connection
+
+    Kirigami.Theme.colorSet: Kirigami.Theme.View
+    Kirigami.Theme.inherit: false
+
+    title: pullRequest ? pullRequest.title : ""
+
+    property string currentFile: ""
+    property string currentText: ""
+
+    onPullRequestChanged: {
+        root.currentFile = ""
+        root.currentText = ""
+    }
+
+    actions: [
+        Kirigami.Action {
+            id: openFiles
+            text: "Files"
+            icon.name: "file-catalog-symbolic"
+            enabled: !!root.pullRequest
+            onTriggered: {
+                if(contextDrawer.opened) {
+                    contextDrawer.close()
+                } else {
+                    contextDrawer.open()
+                }
+            }
+        }
+    ]
+
+    Kirigami.PlaceholderMessage {
+        visible: root.currentFile == ''
+        anchors.centerIn: parent
+        icon.name: "org.deprecated.kodereviewer"
+        text: "No file selected"
+    }
+
+    ColumnLayout {
+        anchors.fill: parent
+        visible: root.currentFile != ''
+        Editor {
+            id: editor
+            Layout.fillWidth: true
+            Layout.fillHeight: true
+            file: root.currentFile
+            text: root.currentText
+        }
+    }
+
+    Connections {
+        target: contextDrawer
+        function onFileSelected(filename, text) {
+            console.log("file changed!")
+            root.currentFile = filename + '.diff'
+            root.currentText = text
+        }
+    }
+}